去年，我們在 GORM 中引入了對 MongoDB 的支援（以及許多其他 GORM 實現），並受到了社群的廣泛好評。我們收到了大量的反饋，今天我們很高興地宣佈一個新的版本（里程碑 2），它解決了我們收到的一些反饋。

嵌入式文件支援

需求排名第一的功能是巢狀文件支援，在此版本中，我們對此進行了重大改進。現在，您可以使用 GORM 中的標準嵌入式對映來嵌入其他域

class Person {
  String firstName
  String lastName
  Address address
  static embedded = ['address']
}

嵌入式域儲存在主 Mongo 文件中的巢狀文件中。此外，基本型別的列表和對映現在也可以持久化到本機 Mongo ArrayList 和雜湊中

class Person {
	List<String> friends
	Map pets
}
...

new Person(friends:['Fred', 'Bob'], pets:[chuck:"Dog", eddie:'Parrot']).save(flush:true)

嵌入式域以及列表和對映都儲存在域的主 Mongo 文件中，從而允許使用 GORM 實現更多常見的 MongoDB 模式。

地理空間索引和查詢

MongoDB 本身支援地理空間索引和查詢，現在 GORM for MongoDB 也支援此功能。您可以將列表或對映定義為“地理索引”

class Hotel {
	String name
	List location
	static mapping = {
		location geoIndex:true
	}
}

然後，可以使用表示緯度和經度的二維列表輕鬆地持久化地理資料

new Hotel(name:"Hilton", location:[50, 50]).save()

或者，您可以使用包含緯度和經度值的對映，這可能更易於閱讀

new Hotel(name:"Hilton", location:[lat: 40.739037, long: 73.992964]).save()

持久化後，可以使用新的 findBy*Near 語法查詢域類

def h = Hotel.findByLocationNear([50, 60])
assert h.name == 'Hilton'

您還可以使用繫結查詢，使用 findBy*WithinBox 方法在矩形內定位位置

def box = [[40.73083, -73.99756], [40.741404,  -73.988135]]
def h = Hotel.findByLocationWithinBox(box)

或使用 findBy*WithinCircle 方法在圓內定位

def center = [50, 50]
def radius = 10
def h = Hotel.findByLocationWithinCircle([center, radius])

無模式域模型

MongoDB 是完全無模式的，這意味著您不受限於關係資料庫中固定數量的列。 GORM for MongoDB 現在支援無模式域模型。您可以繼續在您的域模型中指定您的固定域屬性

class Plant {
    boolean goesInPatch
    String name
}

但是，您現在也可以使用 Groovy 下標運算子來持久化其他屬性

def p = new Plant(name:"Pineapple")
p['color'] = 'Yellow'
p['hasLeaves'] = true
p.save()
p = Plant.findByName("Pineapple")

println p['color']
println p['hasLeaves']

還有許多改進，包括自定義索引建立的能力，對 query-by-example 的支援以及對 GORM API 的更完整支援。該文件已更新，涵蓋了所有這些新功能。讓我們知道您的想法，您的反饋非常寶貴。

最後，如果您在馬德里地區並且想了解更多關於 GORM for MongoDB 的資訊，請在本週四參加Spring IO 會議，那裡將有更多關於 Spring、Grails 和 GORM 的演講。